B4A=true
Group=Default Group
ModulesStructureVersion=1
Type=StaticCode
Version=11.8
@EndOfDesignText@
'Code module
'Subs in this code module will be accessible from all modules.
Sub Process_Globals
	'These global variables will be declared once when the application starts.
	'These variables can be accessed from all modules.
	Dim errorLog As SQL 'Requiere la libreria "SQL"
End Sub

Sub revisaBD 'ignore
	If Not(File.Exists(Starter.rutaBD, "kmt.db")) Then File.Copy(File.DirAssets, "kmt.db", Starter.rutaBD, "kmt.db")
	If Not(Starter.skmt.IsInitialized) Then Starter.skmt.Initialize(Starter.rutaBD, "kmt.db", True)
	Starter.skmt.ExecNonQuery("CREATE TABLE IF NOT EXISTS SUCURSAL(ID_SUC TEXT, NOMBRE_SUC TEXT)")
	Starter.skmt.ExecNonQuery("CREATE TABLE IF NOT EXISTS CHECADO(USUARIO TEXT, ID_EMP TEXT, PERFIL TEXT, PROYECTO TEXT, SUCURSAL TEXT, ESTATUS TEXT, FECHA TEXT)")
	Starter.skmt.ExecNonQuery("CREATE TABLE IF NOT EXISTS HIST_CHECADO(USUARIO TEXT, ID_EMP TEXT, PERFIL TEXT, PROYECTO TEXT, SUCURSAL TEXT, ESTATUS TEXT, FECHA TEXT)")
	Starter.skmt.ExecNonQuery("CREATE TABLE IF NOT EXISTS HIST_PROMOTORIA (HIST_PM_FECHA TEXT, HIST_PR_NOMBRE TEXT,HIST_PR_TELEFONO TEXT, HIST_PR_CORREO TEXT, HIST_PR_CURP TEXT, HIST_PR_INE BLOB, HIST_PR_ESTATUS TEXT, HIST_PR_EVIDENCIA BLOB, HIST_PR_OBSERVACIONES TEXT, HIST_PR_COMENTARIOERROR TEXT, HIST_PR_IDPROYECTO TEXT, HIST_PR_NOMBREPROYECTO TEXT, HIST_PR_IDSUCURSAL TEXT, HIST_PR_NOMBRESUCURSAL TEXT, HIST_PR_USUARIO TEXT, HIST_PR_LATITUD TEXT, HIST_PR_LONGITUD TEXT, HIST_PR_BATERIA TEXT, ENVIADO INT)")
	Starter.skmt.ExecNonQuery("CREATE TABLE IF NOT EXISTS CAT_VARIABLES(CAT_VA_DESCRIPCION TEXT, CAT_VA_VALOR TEXT)")
	Starter.skmt.ExecNonQuery("CREATE TABLE IF NOT EXISTS HIST_SUPERVISOR(HIST_CHKS_PROYECTO TEXT, HIST_CHKS_NOMPROY TEXT, HIST_CHKS_SUCURSAL TEXT,HIST_CHKS_FORMATO TEXT, HIST_CHKS_SUPERVISOR TEXT, HIST_CHKS_PROMOTOR TEXT, HIST_CHKS_FECHA TEXT, HIST_CHKS_ID TEXT, HIST_CHKS_CALIF_MULTIPLE TEXT, HIST_CHKS_CALIF_ABIERTA TEXT, HIST_CHKS_HORARIO TEXT, ENVIADO INT)")
'	Starter.skmt.ExecNonQuery("DROP TABLE IF EXISTS HIST_SUPERVISOR")
	Starter.skmt.ExecNonQuery("CREATE TABLE IF NOT EXISTS trabaja(sitrabaja TEXT)")
	If Not(errorLog.IsInitialized) Then errorLog.Initialize(File.DirInternal, "errorLog.db", True)
	errorLog.ExecNonQuery("CREATE TABLE IF NOT EXISTS errores(fecha INTEGER, error TEXT)")
End Sub

'Limpiamos la tabla errorLog de la BD
Sub deleteErrorLog_DB 'ignore
	errorLog.ExecNonQuery("delete from errores")
	errorLog.ExecNonQuery("vacuum;")
	ToastMessageShow("BD Errores Borrada", False)
End Sub

'Borramos renglones extra de la tabla de errores
Sub borraArribaDe100Errores 'ignore
	revisaBD
	LogColor("Borramos BD de log", Colors.Magenta)
	errorLog.ExecNonQuery("DELETE FROM errores WHERE fecha NOT in (SELECT fecha FROM errores ORDER BY fecha desc LIMIT 99 )")
	errorLog.ExecNonQuery("vacuum;")
	Log("Borramos mas de 100 de errorLog")
End Sub

'Genera una notificacion con importancia alta
Sub notiHigh(title As String, body As String, activity As Object) 'ignore
	Private notif As Notification
	notif.Initialize2(notif.IMPORTANCE_HIGH)
	notif.Icon = "icon"
	notif.Vibrate = False
	notif.Sound = False
	notif.AutoCancel = True
	Log("notiHigh: "&title)
	notif.SetInfo(title, body, activity)
'	Log("notiHigh SetInfo")
	notif.Notify(777)
End Sub

'Regresa el objeto de una notificacion con importancia baja
Sub notiLowReturn(title As String, Body As String, id As Int) As Notification 'ignore
	Private notification As Notification
	notification.Initialize2(notification.IMPORTANCE_LOW)
	Log("notiLowReturn: "&title)
	notification.Icon = "icon"
	notification.Sound = False
	notification.Vibrate = False
	notification.SetInfo(title, Body, Main)
	notification.Notify(id)
'	Log("notiLowReturn SetInfo")
	Return notification
End Sub

Sub IsConnectedToInternet As Boolean 'ignore
	Dim r As Reflector
	r.Target = r.GetContext
	r.Target = r.RunMethod2("getSystemService", "connectivity", "java.lang.String")
	r.Target = r.RunMethod("getActiveNetworkInfo")
	If r.Target <> Null Then
'		If logger Then LogColor("isConnectedOrConnecting", Colors.green)
		Return r.RunMethod("isConnectedOrConnecting")
	End If
'	If logger Then LogColor("Not connected", Colors.red)
	Return False
End Sub

'Convierte una fecha al formato yyMMddHHmmss
Sub fechaKMT(fecha As String) As String 'ignore
'	Log(fecha)
	Dim OrigFormat As String = DateTime.DateFormat  'save orig date format
	DateTime.DateFormat="yyMMddHHmmss"
	Dim nuevaFecha As String=DateTime.Date(fecha)
	DateTime.DateFormat=OrigFormat  'return to orig date format
'	Log(nuevaFecha)
	Return nuevaFecha
End Sub